Мой Kbyte.Ru
Рассылка Kbyte.Ru
Группы на Kbyte.Ru
Партнеры Kbyte.Ru
Реклама
Сделано руками
Сделано руками
> Исходные коды - Microsoft -

Visual Basic .NET - Элементы управления Windows

Все примеры / Интерфейс / Элементы управления Windows

Печать RichTextBox

Автор: Microsoft | добавлено: 29.05.2011, 13:56 | просмотров: 3368 (2+) | комментариев: 0 | рейтинг: *x10
Элемент управления RichTextBox по умолчанию не содержит методов, которые могли бы распечатать его содержимое как есть (с сохранением форматирования, изображений и т.п.). В данном примере содержится наследованный от RichTextBox элемент управления, который позволяет печатать своё содержимое посредства API.

Инструкции

Это элемент управления. Перед его использованием, проект нужно компилировать. Либо можно вынести этот элемент в отдельную сборку (dll) и подключить к своему проекту.
На форме также понадобится элементы PrintDialog, PrintPreviewDialog, PageSetupDialog и PrintDocument.

Также разместите на форме кнопки: btnPageSetup, btnPrint и btnPrintPreview.

Разместите следующий код:
Private checkPrint As Integer

Private Sub PrintDocument1_BeginPrint(ByVa l sender As Object, ByVal e As System.Drawing.Printing.PrintE ventArgs) Handles PrintDocument1.BeginPrint
checkPrint = 0
End Sub

Private Sub PrintDocument1_PrintPage(ByVal sender As Object, ByVal e As System.Drawing.Printing.PrintP ageEventArgs) Handles PrintDocument1.PrintPage
' Print the content of the RichTextBox. Store the last character printed.
checkPrint = RichTextBoxPrintCtrl1.Print(ch eckPrint, RichTextBoxPrintCtrl1.TextLeng th, e)

' Look for more pages
If checkPrint < RichTextBoxPrintCtrl1.TextLeng th Then
e.HasMorePages = True
Else
e.HasMorePages = False
End If
End Sub

Private Sub btnPageSetup_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnPageSetup.Click.Click
PageSetupDialog1.ShowDialog()
End Sub

Private Sub btnPrint_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnPrint.Click
If PrintDialog1.ShowDialog() = DialogResult.OK Then
PrintDocument1.Print()
End If
End Sub

Private Sub btnPrintPreview_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnPrintPreview.Click
PrintPreviewDialog1.ShowDialog ()
End Sub


Подробности смотрите на официальном сайте Microsoft: http://support.microsoft.com/k b/811401

Код

Option Explicit On 

Imports System
Imports System.Windows.Forms
Imports System.Drawing
Imports System.Runtime.InteropServices
Imports System.Drawing.Printing

Namespace RichTextBoxPrintCtrl
   Public Class RichTextBoxPrintCtrl
      Inherits RichTextBox
      ' Convert the unit that is used by the .NET framework (1/100 inch) 
      ' and the unit that is used by Win32 API calls (twips 1/1440 inch)
      Private Const AnInch As Double = 14.4

      <StructLayout(LayoutKind.Sequential)> _
       Private Structure RECT
         Public Left As Integer
         Public Top As Integer
         Public Right As Integer
         Public Bottom As Integer
      End Structure

      <StructLayout(LayoutKind.Sequential)> _
      Private Structure CHARRANGE
         Public cpMin As Integer          ' First character of range (0 for start of doc)
         Public cpMax As Integer          ' Last character of range (-1 for end of doc)
      End Structure

      <StructLayout(LayoutKind.Sequential)> _
      Private Structure FORMATRANGE
         Public hdc As IntPtr             ' Actual DC to draw on
         Public hdcTarget As IntPtr       ' Target DC for determining text formatting
         Public rc As Rect                ' Region of the DC to draw to (in twips)
         Public rcPage As Rect            ' Region of the whole DC (page size) (in twips)
         Public chrg As CHARRANGE         ' Range of text to draw (see above declaration)
      End Structure

      Private Const WM_USER As Integer = &H400
      Private Const EM_FORMATRANGE As Integer = WM_USER + 57

      Private Declare Function SendMessage Lib "USER32" Alias "SendMessageA" (ByVal hWnd As IntPtr, ByVal msg As Integer, ByVal wp As IntPtr, ByVal lp As IntPtr) As IntPtr

      ' Render the contents of the RichTextBox for printing
      '	Return the last character printed + 1 (printing start from this point for next page)
      Public Function Print(ByVal charFrom As Integer, ByVal charTo As Integer, ByVal e As PrintPageEventArgs) As Integer

         ' Mark starting and ending character 
         Dim cRange As CHARRANGE
         cRange.cpMin = charFrom
         cRange.cpMax = charTo

         ' Calculate the area to render and print
         Dim rectToPrint As RECT
         rectToPrint.Top = e.MarginBounds.Top * AnInch
         rectToPrint.Bottom = e.MarginBounds.Bottom * AnInch
         rectToPrint.Left = e.MarginBounds.Left * AnInch
         rectToPrint.Right = e.MarginBounds.Right * AnInch

         ' Calculate the size of the page
         Dim rectPage As RECT
         rectPage.Top = e.PageBounds.Top * AnInch
         rectPage.Bottom = e.PageBounds.Bottom * AnInch
         rectPage.Left = e.PageBounds.Left * AnInch
         rectPage.Right = e.PageBounds.Right * AnInch

         Dim hdc As IntPtr = e.Graphics.GetHdc()

         Dim fmtRange As FORMATRANGE
         fmtRange.chrg = cRange                 ' Indicate character from to character to 
         fmtRange.hdc = hdc                     ' Use the same DC for measuring and rendering
         fmtRange.hdcTarget = hdc               ' Point at printer hDC
         fmtRange.rc = rectToPrint              ' Indicate the area on page to print
         fmtRange.rcPage = rectPage             ' Indicate whole size of page

         Dim res As IntPtr = IntPtr.Zero          

         Dim wparam As IntPtr = IntPtr.Zero
         wparam = New IntPtr(1)

         ' Move the pointer to the FORMATRANGE structure in memory
         Dim lparam As IntPtr = IntPtr.Zero
         lparam = Marshal.AllocCoTaskMem(Marshal.SizeOf(fmtRange))
         Marshal.StructureToPtr(fmtRange, lparam, False)

         ' Send the rendered data for printing 
         res = SendMessage(Handle, EM_FORMATRANGE, wparam, lparam)

         ' Free the block of memory allocated
         Marshal.FreeCoTaskMem(lparam)

         ' Release the device context handle obtained by a previous call
         e.Graphics.ReleaseHdc(hdc)

         ' Return last + 1 character printer
         Return res.ToInt32()
      End Function

   End Class
End Namespace
Об авторе

Microsoft

Microsoft — мировой лидер в области программного обеспечения, ИТ-услуг и решений. Это одна из крупнейших глобальных корпораций, с представительствами более чем в 190 странах мира и 92,7 тыс. сотрудников.
Microsoft
Последние комментарии (всего: 0)

Добавлять комментарии могут только зарегистрированные пользователи сайта.
Если у Вас уже есть учетная запись на Kbyte.Ru, пройдите процедуру авторизации OpenID.
Если Вы еще не зарегистрированы на Kbyte.Ru - зарегистрируйтесь.


Нет комментариев...

Авторизация
 
OpenID
Зарегистрируйся и получи 10% скидку на добавление своего сайта в каталоги! Подробнее »
Поиск по сайту
Реклама
Счетчики